Vimプラグインlightline導入

前回 Cygwin+screenで256 colorを有効にするというのを書いたので、その表示させたかったVimのステータスラインについて。

lightline

lightline

lightlineは Vimのステータスラインを綺麗に表示させてくれるプラグインです。

Vimには元々vim-powerline (とその後継のpowerline) というPythonを使ったプラグインがありましたが、最近、vim-airline というプラグインが出来て、純粋Vim Scriptなので速いし、他のプラグインとの融合等もあって嬉しい、ということで移行した、と言う人が増えていました。

元々vim-powerlineはもっさりする気がして一度入れてから外してましたが、すごい話題になってたのでまずvim-airlineを入れてみました。

そんな中、lightline というプラグインが登場。 vim-airlineをさらに拡張性高くしたような感じで、さらに作者の方のブログ ¹ではその設計思想まで熱く語られています。

ということで、vim-airlineを導入したばかりでしたが、 lightlineも試してみることに。ちょっと使ってみてとても拡張性が高いのが楽しい所です。

追記: 2017/09/24

下の方法だとちょっと表示順などをきちんと考えられてないのでもうちょっとちゃんとしたのに変更しています。

Vimのlightlineでのステータスライン表示の調整

追記ここまで

取り敢えず置いてみた設定はこんな感じ。

lightline_settings.vim

" lightline.vim {{{
if ! empty(neobundle#get("lightline.vim"))
  let g:lightline = {
    \"colorscheme": "jellybeans",
    \"active": {
      \"left": [["mode", "filename"], ["fugitive"]],
      \"right": [["lineinfo"], ["fileinfo"]]},
    \"component_visible_condition": {
      \"fugitive": '(exists("*fugitive#head") && ""!=fugitive#head())'},
    \'component_function': {
      \'mode': 'MyMode',
      \'filename': 'MyFileName',
      \'fugitive': 'MyFugitive',
      \'fileinfo': 'MyFileInfo',
      \'lineinfo': 'MyLineInfo',
      \},
    \ 'separator': { 'left': '', 'right': '' },
    \ 'subseparator': { 'left': '', 'right': '' }
    \}
  let g:lightline.inactive = g:lightline.active

  function! MyMode()
    let l:ps = ''
    if &paste
      let l:ps = " P"
    endif
    return lightline#mode() . l:ps
  endfunction

  function! MyFileName()
    let l:fn = expand("%:t")
    let l:ro = &ft !~? 'help' && &readonly ? " RO" : ""
    let l:mo = &modifiable && &modified ? " +" : ""
    return l:fn . l:ro . l:mo
  endfunction

  function! MyFugitive()
    let l:fu = exists('*fugitive#head') ? fugitive#head() : ''
    return winwidth('.') >=
          \  strlen(MyMode()) + 2
          \+ strlen(MyFileName()) + 2
          \+ strlen(l:fu) + 2
          \+ strlen(MyLineInfo()) + 2
          \? l:fu : ''
  endfunction

  function! MyFileInfo()
    let l:ff = &fileformat
    let l:fe = (strlen(&fenc) ? &fenc : &enc)
    let l:ft = (strlen(&filetype) ? &filetype : 'no')
    let l:fi = l:ff . " " . l:fe . " " . l:ft
    return winwidth('.') >=
          \  strlen(MyMode()) + 2
          \+ strlen(MyFileName()) + 2
          \+ strlen(MyFugitive())
          \+ ((exists("*fugitive#head") && ""!=fugitive#head()) ? 2 : 0)
          \+ strlen(l:fi) + 2
          \+ strlen(MyLineInfo()) + 2
          \? l:fi : ''
  endfunction

  function! MyLineInfo()
    let l:cl = line(".")
    let l:ll = line("$")
    let l:cc = col(".")
    let l:li = printf("%4d/%d:%3d", l:cl, l:ll, l:cc)
    return winwidth('.') >=
          \  strlen(MyFileName()) + 2
          \+ strlen(l:li) + 2
          \? l:li : ''
  endfunction
endif
"}}} lightline.vim